dev-jjong

주소

dev-jjong — Thu, 12 Mar 2026 14:23:06 +0900

https://www.tsilson24.or.kr/claim/app/out/insuranceLoading?key1=342B571060F078380D722B13D816C808&key2=C406C359BC7162F0278ADA9A74FCCE19

[ORACLE] PL/SQL Autonomous (자율 트랜잭션)

dev-jjong — Tue, 30 Jul 2024 10:48:28 +0900

create or replace function seq_nextval(l_gubun number) return number
as
    pragma autonomous_transaction;
    l_new_seq seq_tab.seq%type;
begin
    update seq_tab
    set	seq = seq+1
    where gubun = l_gubun;
    
    select seq into l_new_seq
    from seq_tab
    where gubun = l_gubun;
    
    commit;
    return l_new_seq;
end;

PL/SQL 함수/프로시저르 자율 트랜잭션으로 선언하면, 그 내부에서 커밋을 수행해도 메인 트랜잭션은 커밋하지 않은 상태로 남는다.

메인 트랜잭션 INSERT 문에서 아래와 같이 채번 함수를 호출하고 최종적으로 커밋하지 전까지 다른 작업을 많이 수행하더라도 채번 테이블 로우 Lock은 이미 해제한 상태이므로 다른 트랜잭션을 블록킹하지 않는다.

insert into target_tab values (seq_nextval(123), :x, :y, :z);

[ORACLE] 21C XE에서 ORA-12543: TNS:수신지 호스트에 도달할 수 없습니다. 오류해결방법

dev-jjong — Wed, 17 Jul 2024 11:03:11 +0900

ORA-12543: TNS:수신지 호스트에 도달할 수 없습니다. 오류해결방법

오류 원인1

- 방화벽 문제 (1521포트를 열지 않았을 경우)

오류 원인2

- 관리자 비밀번호에 @가 들어가 있을 경우

- @는 구분자로 인식하여 로그인이 정상적으로 안된다함.

- 관리자 비밀번호를 변경 후 재시도하면 정상적으로 동작함.

(관리자 비밀번호 변경 방법 : https://fakegrowthup.tistory.com/253)

[ORACLE] Direct Path Insert

dev-jjong — Thu, 27 Jul 2023 09:06:53 +0900

일반적인 Insert가 느린 이유는

데이터를 입력할 수 있는 블록을 Freelist에서 찾는다.
(Freelist란? HWM 아래쪽에 있는 블록중 입력이 가능한 블록에 대한 목록)
(HWM란? High-Water-Mart. 즉, 테이블 데이터가 쌓여있는 가장 높은 영역)
Freelist에서 할당받은 블록을 버퍼캐시에서 찾는다.
버퍼캐시에 없으면, 데이터파일에서 읽어 버퍼캐시에 적재한다.
INSERT 내용을 Undo 세그먼트에 기록한다.
(Undo란? 트랜젝션을 롤백하기 위해 기록한 정보)
INSERT 내용을 Redo 로그에 기록한다.
(Redo란? 트랜젝션을 리커버리 하기위한 정보)

Direct Path Insert 방식이 빠른 이유는

Freelist를 참조하지 않고 HWM 바깥 영역에 데이터를 순차적으로 입력한다.
블록을 버퍼캐에서 탐색하지 않는다.
버퍼캐시에 적재하지 않고, 데이터파일에 직접 기록한다.
Undo 로깅을 안 한다.
(HWM 뒤쪽에 데이터를 순차적으로 입력하기 때문이다. 이 데이터는 커밋하기 전까지 다른 세션이 읽지 않으므로 Redo Consistency를 위해 Undo 데이터를 남기지 않아도 된다.)
Redo 로깅을 안하게 할 수 있다.
(alter table t NOLOGGING;)

Direct Path Insert가 가능한 케이스

INSERT ··· SELECT문에 append 힌트 사용
parallel 힌트를 이용해 병렬 모드로 INSERT
direct 옵션을 지정하고 SQL*Loader(sqlldr)로 데이터 적재 (무슨말일까..)
CTAS(create table ··· as select) 문 수행

Direct Path Insert시 주의할 점

성능은 빨라지지만 Exclusive 모드 TM Lock이 걸린다. 즉, 커밋하기 전까지 다른 트랜잭션은 해당 테이블에 DML을 수행하지 못한다.
Freelist를 조회하지 않고 HWM 바깥 영역에 입력하므로 테이블에 여유 공간이 있어도 재활용하지 않는다.

[ORACLE] 데이터베이스 CALL이 성능에 미치는 영향 테스트

dev-jjong — Wed, 26 Jul 2023 09:16:32 +0900

create table source
as
select b.no, a.*
from (select * from emp where rownum <= 10) a,
     (select rownum as no from dual connect by level <= 100000)b;


create table target
as
select * from source where 1=2;

source 테이블에는 100만건의 데이터가 들어있다.

1. loop가 종료된 후에 커밋 (수행시간: 15초)

source 테이블의 데이터를 target 테이블로 PL/SQL의 루프를 돌려서 건건이 입력해보자.

begin
  for s in (select * from source)
  loop
	  insert into target values(s.no, s.empno, s.ename, s.job, s.mgr, s.hiredate, s.sal, s.comm, s.deptno);
	  
  end loop;
  commit;
end;
/

/*
==========================[Start Time : 2023/07/26 08:57:05]==========================
실행 완료. Time used: 15116 Millis

*/

15초가량 시간이 걸렸다. 루프를 돌면서 건건이 call이 발생했지만, 네트워크를 경유하지 않는 Recursive Call이라서

그나마 15초만에 수행이 된 것이다.

2. loop안쪽에서 건건히 commit (수행시간: 48초)

이번에는 아래 PL/SQL문을 실행해보자.

커밋을 루프 안쪽으로 옮겨보았다.

begin
  for s in (select * from source)
  loop
	  insert into target values(s.no, s.empno, s.ename, s.job, s.mgr, s.hiredate, s.sal, s.comm, s.deptno);
	  commit;
  end loop;
  
end;
/

/*
==========================[Start Time : 2023/07/26 08:54:35]==========================
실행 완료. Time used: 48607 Millis
*/

15초 걸리던게 48초로 늘어났다. 성능도 문제지만 커밋을 이렇게 자주하게 되면 트랜잭션 원자성에도 문제가 생긴다.

3. loop안쪽에서 적당한 주기로 commit (수행시간: 18초)

declare
i NUMBER :=0;
begin
  for s in (select * from source)
  loop
	  insert into target values(s.no, s.empno, s.ename, s.job, s.mgr, s.hiredate, s.sal, s.comm, s.deptno);
	  i := i+1;
	  if mod(i, 100000) = 0 then --10만 번에 한 번씩 커밋
	  commit;
	  end if;
  end loop;
  
end;
/

/*
==========================[Start Time : 2023/07/26 09:09:32]==========================
실행 완료. Time used: 18633 Millis
*/

이렇게 처리하면 맨 마지막에 한 번 커밋하는 것과 비교해서 크게 성능차이가 없다.

4. One SQL로 처리하는 방법 (수행시간: 0.8초)

insert into target 
select * from source;

/*
==========================[Start Time : 2023/07/26 09:12:29]==========================
실행 완료. Time used: 796 Millis
*/

단 한 번의 call로 처리하니 0.8초만에 수행이 되었다.

가급적 One SQL로 처리하도록 하자!!

[ORACLE] 월별 누적 매출 예제

dev-jjong — Wed, 22 Feb 2023 15:03:07 +0900

sqld, sqlp 2과목의 단골 문제죠~~

간단한 예제로 직접 해보면 이해하기 쉽습니다.

먼저 사전에 emp, dept 테이블이 없으시면 아래 링크로 가서 생성하시고, 실습하시면 됩니다.

1. dept, emp 테이블 생성

https://java7.tistory.com/164

2. 월별 누적 매출 예제

create table 월별지점매출
as
select deptno "지점"
     , row_number() over (partition by deptno order by empno) "판매월"
     , round(dbms_random.value(500, 1000)) "매출"
  from emp
 order by deptno;
 
select * from 월별지점매출;


-- 분석함수 이용
select 지점, 판매월, 매출
     , sum(매출) over(partition by 지점 order by 판매월 range between unbounded preceding and current row) 누적매출
  from 월별지점매출;
  
  
-- 조인 이용
select t1.지점, t1.판매월, min(t1.매출) 매출, sum(t2.매출) 누적매출
  from 월별지점매출 t1, 월별지점매출 t2
 where t2.지점 = t1.지점
   and t2.판매월 <= t1.판매월
 group by t1.지점, t1.판매월
 order by t1.지점, t1.판매월

3. 실행결과

[ORACLE] emp, dept 테이블 생성 스크립트

dev-jjong — Wed, 22 Feb 2023 14:11:18 +0900

오라클 테스트시 많이 사용되는 emp, dept 테이블의 스크립트입니다.

scoot계정에 기본으로 되어있지 않은 경우 아래 스크립트를 이용해서 생성하시면 됩니다.

CREATE TABLE DEPT
       (DEPTNO number(10),
        DNAME VARCHAR2(14),
        LOC VARCHAR2(13) 
);

INSERT INTO DEPT VALUES (10, 'ACCOUNTING', 'NEW YORK');
INSERT INTO DEPT VALUES (20, 'RESEARCH',   'DALLAS');
INSERT INTO DEPT VALUES (30, 'SALES',      'CHICAGO');
INSERT INTO DEPT VALUES (40, 'OPERATIONS', 'BOSTON');

CREATE TABLE EMP (
 EMPNO               NUMBER(4) NOT NULL,
 ENAME               VARCHAR2(10),
 JOB                 VARCHAR2(9),
 MGR                 NUMBER(4) ,
 HIREDATE            DATE,
 SAL                 NUMBER(7,2),
 COMM                NUMBER(7,2),
 DEPTNO              NUMBER(2) 
 );

INSERT INTO EMP VALUES (7839,'KING','PRESIDENT',NULL,TO_DATE('1981-11-17','YYYY-MM-DD'),5000,NULL,10);
INSERT INTO EMP VALUES (7698,'BLAKE','MANAGER',7839,TO_DATE('1981-05-01','YYYY-MM-DD'),2850,NULL,30);
INSERT INTO EMP VALUES (7782,'CLARK','MANAGER',7839,TO_DATE('1981-05-09','YYYY-MM-DD'),2450,NULL,10);
INSERT INTO EMP VALUES (7566,'JONES','MANAGER',7839,TO_DATE('1981-04-01','YYYY-MM-DD'),2975,NULL,20);
INSERT INTO EMP VALUES (7654,'MARTIN','SALESMAN',7698,TO_DATE('1981-09-10','YYYY-MM-DD'),1250,1400,30);
INSERT INTO EMP VALUES (7499,'ALLEN','SALESMAN',7698,TO_DATE('1981-02-11','YYYY-MM-DD'),1600,300,30);
INSERT INTO EMP VALUES (7844,'TURNER','SALESMAN',7698,TO_DATE('1981-08-21','YYYY-MM-DD'),1500,0,30);
INSERT INTO EMP VALUES (7900,'JAMES','CLERK',7698,TO_DATE('1981-12-11','YYYY-MM-DD'),950,NULL,30);
INSERT INTO EMP VALUES (7521,'WARD','SALESMAN',7698,TO_DATE('1981-02-23','YYYY-MM-DD'),1250,500,30);
INSERT INTO EMP VALUES (7902,'FORD','ANALYST',7566,TO_DATE('1981-12-11','YYYY-MM-DD'),3000,NULL,20);
INSERT INTO EMP VALUES (7369,'SMITH','CLERK',7902,TO_DATE('1980-12-09','YYYY-MM-DD'),800,NULL,20);
INSERT INTO EMP VALUES (7788,'SCOTT','ANALYST',7566,TO_DATE('1982-12-22','YYYY-MM-DD'),3000,NULL,20);
INSERT INTO EMP VALUES (7876,'ADAMS','CLERK',7788,TO_DATE('1983-01-15','YYYY-MM-DD'),1100,NULL,20);
INSERT INTO EMP VALUES (7934,'MILLER','CLERK',7782,TO_DATE('1982-01-11','YYYY-MM-DD'),1300,NULL,10);

COMMIT;

[ORACLE] 21C에서 사용자 계정 생성하기

dev-jjong — Wed, 15 Feb 2023 14:15:49 +0900

--1. SQL PLUS 실행 후 sys계정으로 접속
conn /as sysdba

--2. 사용자 계정 생성
--참고: 21c에서 사용자 계정을 생성하려면 "c##" 수식어를 앞에 붙여야한다.
create user c##sqlp identified by 20230319;

--3. 사용자 권한 설정
grant create any table to c##sqlp;
grant connect, resource, dba to c##sqlp;

--4. 테이블스페이스 권한 부여
alter user c##sqlp default tablespace users quota unlimited on users;

--5. 생성한 계정으로 재로그인
conn c##sqlp;
비밀번호: 20230319

--6. 접속한 계정 확인
show user;

[ORACLE] 바인드 변수의 중요성

dev-jjong — Mon, 9 Jan 2023 14:28:30 +0900

1. 개요

바인드 변수를 사용하게 되면, 커서를 많이 생성하지 않고 하나를 반복 재사용하므로 메모리 사용량과 파싱 소요시간을 줄여준다.궁극적으로, 시스템 전반의 메모리와 CPU 사용률을 낮춰 데이터베이스 성능과 확장성을 높이는게 기여하고, 특히 동시 사용자 접속이 많을 때는 그 영향력이 절대적이다.아래 간단한 실습을 통해 바인드 변수에 대해 알아보자.

2. 실습 환경 설정

-- 테이블 생성
create table t
as
select * from all_objects;

update t set object_id = rownum;

-- 인덱스 생성
create unique index t_idx on t(object_id);

-- 통계정보 수집
analyze table t compute statistics;

-- 인덱스를 잘 타는지 실행계획 확인 
set autotrace traceonly explain; -- 실행계획을 보기위한 sql plus 문법
select object_name from t where object_id = 1000;
set autotrace off; -- 실행계획을 안보기 위한 sql plus 문법

alter system flush shared_pool;

3. 실습

첫 번째, 바인드 변수 사용

-- SQL 트레이스 수집 시작
alter session set sql_trace = true;

-- 바인드 변수 방식으로 20000회 실행
declare
	type rc is ref cursor;
	l_rc rc;
	l_object_name t.object_name%type;
BEGIN
	for i in 1..20000
	loop
		open l_rc for
			'select /* test1 */ object_name
			 from   t
			 where  object_id = :x' using i;
		fetch l_rc into l_object_name;
		close l_rc;
	end loop;
end;
/

--PL/SQL 처리가 정상적으로 완료되었습니다.
--경   과: 00:00:03.91

select * from dual;

-- SQL 트레이스 수집 종료
alter session set sql_trace = false;

V$SQL의 결과를 확인해보면, 2만번의 쿼리 콜이 있었지만 하드파싱은 1번뿐 인것을 알 수 있다.

select sql_text, loads, parse_calls, executions, fetches from v$sql
where  sql_text like '%test1%'
and    sql_text not like '%v$sql%'
and    sql_text not like '%declare%';

*LOADS =1 (하드파싱 1번)

아래 SQL TRACE에도 위와 동일한 결과를 볼 수 있다.

*Misses in library cache during parse: 1  (하드파싱 1번)

두 번째, 바인드 변수 미사용(즉, 상수 사용)

-- SQL 트레이스 수집 시작
alter session set sql_trace = true;

-- 상수값 입력 방식으로 20000회 실행
declare
	type rc is ref cursor;
	l_rc rc;
	l_object_name t.object_name%type;
BEGIN
	for i in 1..20000
	loop
		open l_rc for
			'select /* test2 */ object_name
			 from   t
			 where  object_id = ' || i;
		fetch l_rc into l_object_name;
		close l_rc;
	end loop;
end;
/	

--PL/SQL 처리가 정상적으로 완료되었습니다.
--경   과: 00:00:53.91

select * from dual;

-- SQL 트레이스 수집 종료
alter session set sql_trace = false;

아래 V$SQL의 결과를 보면 WHERE절에 새로운 조건절이 대입 될때마다 캐시에 새로운 커서가 생성된 것을 볼 수 있다.

또한 매번 하드파싱을 하게된 꼴이고, 처리 시간 또한 기존에 비해 몇배가 더 걸리게 되었다.

"제일 중요한 사실은 20,000번 커서를 생성했지만, 캐시에 남아있는건 3400여개 뿐이였다.

나머지는 이미 캐시에서 밀려나고 없기 때문이다."

select substr(sql_text, 61), loads, parse_calls, executions, fetches from v$sql
where  sql_text like '%test2%'
and    sql_text not like '%v$sql%'
and    sql_text not like '%declare%';

[ORACLE] 커서 공유 테스트

dev-jjong — Thu, 5 Jan 2023 10:07:57 +0900

alter system flush shared_pool;

-- 1회 실행
select /* cursor_test */ empno, ename, job, sal, deptno
from EMP where empno = 7788;


select sql_id, parse_calls, loads, executions, invalidations, decode(sign(invalidations), 1, (loads-invalidations), 0) reloads
from v$sql
where sql_text like '%cursor_test%'
and sql_text not like '%v$sql%';

-- 2회 실행
select /* cursor_test */ empno, ename, job, sal, deptno
from EMP where empno = 7788;

-- 3회 실행
select /* cursor_test */ empno, ename, job, sal, deptno
from EMP where empno = 7788;


select sql_id, parse_calls, loads, executions, invalidations, decode(sign(invalidations), 1, (loads-invalidations), 0) reloads
from v$sql
where sql_text like '%cursor_test%'
and sql_text not like '%v$sql%';

parse_calls: 라이브러리 캐시에서 SQL커서를 찾으려는 요청 횟수

loads: 하드파싱을 거친 SQL 실행계획을 라이브러리 캐시에 적재한 횟수

executions: SQL을 실행한 횟수

invalidations: 커서가 무효화된 횟수. 커서가 참조하고 있는 오브젝트에 중요한 변화가 일어난 경우